build.gradle

plugins {
    id "java"
    id "org.springframework.boot" version "3.3.1"
    id "io.spring.dependency-management" version "1.1.5"
    id "com.palantir.git-version" version "3.1.0"
    id "com.adarshr.test-logger" version "4.0.0"
    id "jacoco"
}

repositories {
    mavenCentral()
}

group = "com.trynoice"
version = gitVersion().substring(1) // remove leading 'v' from the Git tag

sourceSets {
    integrationTest {
        compileClasspath += sourceSets.main.output
        runtimeClasspath += sourceSets.main.output
    }
}

configurations {
    integrationTestImplementation.extendsFrom implementation
    integrationTestRuntimeOnly.extendsFrom runtimeOnly
}

springBoot {
    buildInfo()
}

bootRun {
    systemProperty "spring.profiles.active", "dev-default,dev"
}

bootJar {
    archiveFileName = "${archiveBaseName.get()}.${archiveExtension.get()}"
    exclude 'application-dev*.properties'
}

tasks.withType(Test) {
    useJUnitPlatform()
    finalizedBy jacocoTestReport
    systemProperty "spring.profiles.active", "test"
}

task integrationTest(type: Test) {
    description = 'Runs the integration tests.'
    group = 'verification'
    shouldRunAfter test

    classpath = sourceSets.integrationTest.runtimeClasspath
    testClassesDirs = sourceSets.integrationTest.output.classesDirs
}

check.dependsOn integrationTest

jacocoTestReport {
    executionData fileTree(buildDir).include("/jacoco/*.exec")

    reports {
        xml.required = true
    }
}

dependencies {
    def flywayVersion = '10.15.0'
    def springDocVersion = '2.5.0'
    def therapiVersion = '0.15.0'

    // to enable JavaDoc support in SpringDocs
    annotationProcessor "com.github.therapi:therapi-runtime-javadoc-scribe:$therapiVersion"
    annotationProcessor 'org.projectlombok:lombok'

    compileOnly 'org.projectlombok:lombok'

    developmentOnly 'org.springframework.boot:spring-boot-devtools'

    implementation 'com.auth0:java-jwt:4.4.0'
    implementation 'com.github.ben-manes.caffeine:caffeine:3.1.8'
    implementation "com.github.therapi:therapi-runtime-javadoc:$therapiVersion" // for javadoc support in springdoc
    implementation 'com.google.apis:google-api-services-androidpublisher:v3-rev20240624-2.0.0'
    implementation 'com.google.auth:google-auth-library-oauth2-http:1.23.0'
    implementation 'com.stripe:stripe-java:26.1.0'
    implementation 'org.apache.commons:commons-text:1.12.0'
    implementation "org.flywaydb:flyway-core:$flywayVersion"
    implementation "org.flywaydb:flyway-database-postgresql:$flywayVersion"
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-cache'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.integration:spring-integration-core'
    implementation "org.springdoc:springdoc-openapi-starter-common:$springDocVersion"
    implementation "org.springdoc:springdoc-openapi-starter-webmvc-ui:$springDocVersion"
    implementation 'org.postgresql:postgresql'

    implementation platform('software.amazon.awssdk:bom:2.26.12')
    implementation 'software.amazon.awssdk:s3'
    implementation 'software.amazon.awssdk:ses'

    implementation platform('com.google.cloud:spring-cloud-gcp-dependencies:5.4.3')
    implementation 'com.google.cloud:spring-cloud-gcp-starter-pubsub'


    testAnnotationProcessor 'org.projectlombok:lombok'

    testCompileOnly 'org.projectlombok:lombok'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'


    integrationTestAnnotationProcessor 'org.projectlombok:lombok'

    integrationTestCompileOnly 'org.projectlombok:lombok'

    integrationTestImplementation 'org.springframework.boot:spring-boot-starter-test'
    integrationTestImplementation 'org.testcontainers:postgresql:1.19.8'
}