-
Notifications
You must be signed in to change notification settings - Fork 0
/
IntegrateAlgebraic.m
7165 lines (4841 loc) · 220 KB
/
IntegrateAlgebraic.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(* ::Title:: *)
(*IntegrateAlgebraic*)
(* ::Subtitle:: *)
(*Sam Blake, 2020*)
(* ::Text:: *)
(* ::Text:: *)
(*Started on 16 March 2020.*)
(* ::Input:: *)
(*(* This is a deficiency! *)*)
(*IntegrateAlgebraic[1/(2-5 x+10 x^2-10 x^3+5 x^4-x^5)^(1/5),x]*)
(*1+Factor[-1+2-5 x+10 x^2-10 x^3+5 x^4-x^5]*)
(* ::Input:: *)
(*(* This is an embarrassing bug! *)*)
(*groebnerSubstitute[-((2 u^3 Sqrt[-1+u^4] (Sqrt[2]-2 Sqrt[2] u^2-Sqrt[2] u^4))/((-1+u) (1+u) (1+u^2) (-1-2 u^2+u^4)^2)),t->u^2,u]*)
(* ::Input:: *)
(*(* This is horrendous! *)*)
(*IntegrateAlgebraic[1/((x+b)^2 (a x^2+b x+c)^(3/2)),x]*)
(* ::Subsection::Closed:: *)
(*Implementation details*)
(* ::Input:: *)
(*$verboseLevel=0;*)
(*int=IntegrateAlgebraic;*)
(* ::Text:: *)
(*The following are some notes on the design and implementation of IntegrateAlgebraic. This package implements a suite of heuristics for solving algebraic integrals. The methods used are summarised below:*)
(* ::Subsubsection::Closed:: *)
(*rationalUndeterminedIntegrate*)
(* ::Text:: *)
(*The most effective method within IntegrateAlgebraic is rationalUndeterminedIntegrate. This method uses a combination of integration by substitution (using a Laurent polynomial) and the method of undetermined coefficients to integrate an algebraic function which differs from the original integrand by a branch cut, the correct for the branch cut introduced during the integration. The _rational part_ of the integral is computed using GroebnerBasis. (Two notes on this: 1. My definition for the _rational part_ differs to the Risch algorithm, where the _rational part_ is computed using Hermite reduction. 2. As an alternative to using GroebnerBasis, another method based on undetermined coefficients, solveRationalUndetermined, may be used.) This method is described in the paper https://arxiv.org/abs/2004.04910. For example, for the following integral we use the substitution u == (-1 + x^4 + x^6)/x^2:*)
(* ::Input:: *)
(*IntegrateAlgebraic[((1-x^2+2 x^4) Sqrt[-1+x^2+x^4+x^6])/((-1+x^2) (1+x^2) (-1+x^4+x^6)),x]//Timing*)
(* ::Input:: *)
(*Integrate[Sqrt[1+u]/(2 (-1+u) u),u]*)
(*%/.u -> (-1+x^4+x^6)/x^2;*)
(*PowerExpand[Together //@ % ]*)
(*D[%,x] - ((1-x^2+2 x^4) Sqrt[-1+x^2+x^4+x^6])/((-1+x^2) (1+x^2) (-1+x^4+x^6)) // Simplify*)
(* ::Subsubsection::Closed:: *)
(*directRationalise*)
(* ::Text:: *)
(*The second most effective method is directRationalise. This method uses a substitution of the form u = p[x]/q[x]/(r[x])^(n/m) to directly transform the algebraic integral to a rational function of u. This method is a generalisation of a method of integration by Gunther (Ref: G\[UDoubleDot]nther, S. (1882). "Sur l'\[EAcute]valuation de certaines int\[EAcute]grales pseudo-elliptiques". Bulletin de la S. M. F. vol. 10. pp. 88-97.). *)
(*For example, the following integral is computed with the substitution u == x/(1 + x^2)^(1/3):*)
(* ::Input:: *)
(*IntegrateAlgebraic[(3 + x^2)/((-1 - x^2 + x^3)*(1 + x^2)^(1/3)), x]*)
(*D[%, x] - (3 + x^2)/((-1 - x^2 + x^3)*(1 + x^2)^(1/3)) // Simplify*)
(* ::Input:: *)
(*Integrate[3/(-1 + u^3), u] /. u -> x/(1 + x^2)^(1/3)*)
(*D[%, x] - (3 + x^2)/((-1 - x^2 + x^3)*(1 + x^2)^(1/3)) // Simplify*)
(* ::Subsubsection::Closed:: *)
(*logPartIntegrate*)
(* ::Text:: *)
(*logPartIntegrate is a very specific method for integrals of the form Integrate[a[x]/(b[x] Sqrt[r[x]]), x] == c Log[p[x] + q[x] r[x]], where c is a constant and a[x], b[x], p[x], q[x] and r[x] are polynomials. These methods were motivated by an integral posted by Henri Cohen in sci.math.symbolic in 1993. (Ref: https://groups.google.com/g/sci.math.symbolic/c/BPOIUsVMuY0/m/2moCKQY_cz4J): *)
(* ::Input:: *)
(*IntegrateAlgebraic[x/Sqrt[-71-96 x+10 x^2+x^4],x]*)
(* ::Subsubsection::Closed:: *)
(*linearRationalIntegrate*)
(* ::Text:: *)
(*linearRationalIntegrate uses the substitution u = = (x+a)/(x+b). For example, for the following integral linearRationalIntegrate computes the substitution u == (x-1)/(x+1) which reduces the integral to (2*u^(1/3))/(-1 + u)^2:*)
(* ::Input:: *)
(*IntegrateAlgebraic[(-1+x)/(x^3-x^2-x+1)^(1/3),x]*)
(* ::Subsubsection::Closed:: *)
(*decreasePolynomialRadicandDegreeIntegrate*)
(* ::Text:: *)
(*decreasePolynomialRadicandDegreeIntegrate attempts to factor the radicand and introduce branch cuts. For example, for the following integral we factor the radicand:*)
(* ::Input:: *)
(*Factor[-8+12 x+54 x^2-135 x^3+81 x^4]*)
(* ::Text:: *)
(*So we can write (-8+12 x+54 x^2-135 x^3+81 x^4)^(1/3) as (3 x-2)(3 x+1)^(1/3):*)
(* ::Input:: *)
(*IntegrateAlgebraic[1/(-8+12 x+54 x^2-135 x^3+81 x^4)^(1/3),x]*)
(* ::Input:: *)
(*Integrate[1/((3 x-2)(3 x+1)^(1/3)),x]/.(1+3 x)^(1/3)->(-8+12 x+54 x^2-135 x^3+81 x^4)^(1/3)/(3 x-2)*)
(*D[%,x]-1/(-8+12 x+54 x^2-135 x^3+81 x^4)^(1/3)//Simplify*)
(* ::Subsubsection::Closed:: *)
(*goursatIntegrate*)
(* ::Text:: *)
(*The goursatIntegrate method implements Goursat's reduction for quartic radicands to biquadratics. This method can be greatly expanded. In particular, it would seem that Martin Weltz has made some extensions to Goursat's work for cube roots (based on numerous posts to sci.math.symbolic). *)
(* ::Text:: *)
(** We can integrate all integrands in Q(x, (a x + b)^(m_1/n_1), (a x + b)^(m_2/n_2), ...) with the substitution u^n = a x + b, where n = lcm(n_1, n_2, ...).*)
(* ::Text:: *)
(** We can integrate all integrands in Q(x, (a x^2 + b x + c)^(n_1/2), (a x^2 + b x + c)^(n_2/2), ...), as these are always elementary integrable. The latter uses Euler's substitution, which in some instances will produce larger results than necessary, for example:*)
(* ::Input:: *)
(*IntegrateAlgebraic[Sqrt[1-x+x^2]/(x^4+x^2),x]*)
(* ::Text:: *)
(*In comparison, here's the result from Rubi (which does a nice job of this integral, but cannot integrate all integrands in Q(x, (a x^2 + b x + c)^(n_1/2), (a x^2 + b x + c)^(n_2/2), ...)):*)
(* ::Input:: *)
(*D[-(Sqrt[1-x+x^2]/x)-ArcTan[(1+x)/(Sqrt[2] Sqrt[1-x+x^2])]/Sqrt[2]-ArcTanh[(1-x)/(Sqrt[2] Sqrt[1-x+x^2])]/Sqrt[2]+1/2 ArcTanh[(2-x)/(2 Sqrt[1-x+x^2])],x]-Sqrt[1-x+x^2]/(x^4+x^2)//Simplify*)
(* ::Subsubsection::Closed:: *)
(*expandIntegrate*)
(* ::Text:: *)
(*expandIntegrate uses Expand to integrate term-by-term on integrals we cannot do without expansion. For example, we cannot compute the following integral:*)
(* ::Input:: *)
(*IntegrateAlgebraic[(a + b x)/((2 - x^2) (x^2 - 1)^(1/4)), x]*)
(* ::Text:: *)
(*But expanding into a sum of two terms we are successful: *)
(* ::Input:: *)
(*IntegrateAlgebraic[a/((2 - x^2) (x^2 - 1)^(1/4)), x]*)
(*IntegrateAlgebraic[b x/((2 - x^2) (x^2 - 1)^(1/4)), x]*)
(* ::Text:: *)
(*This is what we do with the option "Expansion" -> True:*)
(* ::Input:: *)
(*IntegrateAlgebraic[(a + b x)/((2 - x^2) (x^2 - 1)^(1/4)), x,\[NonBreakingSpace]"Expansion" -> True]*)
(* ::Subsubsection::Closed:: *)
(*apartIntegrate*)
(* ::Text:: *)
(*apartIntegrate methods uses partial fractions over Q, then over K to expand the integrand into a sum of terms. Like expandIntegrate, this method is only used after we have found that we cannot integrate the original integrand. For example, we cannot integrate the following:*)
(* ::Input:: *)
(*IntegrateAlgebraic[1/((1-3 x^2)^(1/3) (-3+x^2)),x]*)
(* ::Text:: *)
(*Using a partial fraction expansion and integrating term-by-term we get *)
(* ::Input:: *)
(*Apart[1/(y Factor[-3+x^2,Extension->Sqrt[3]]),x]/.y->(1-3 x^2)^(1/3)*)
(* ::Input:: *)
(*IntegrateAlgebraic[1/(2 Sqrt[3] (-Sqrt[3]+x) (1-3 x^2)^(1/3)),x]*)
(*IntegrateAlgebraic[-(1/(2 Sqrt[3] (Sqrt[3]+x) (1-3 x^2)^(1/3))),x]*)
(* ::Text:: *)
(*Which is, more or less, what IntegrateAlgebraic does with the option "Expansion" -> True:*)
(* ::Input:: *)
(*IntegrateAlgebraic[1/((1-3 x^2)^(1/3) (-3+x^2)),x,"Expansion" -> True]*)
(* ::Subsubsection::Closed:: *)
(*integrateNestedRadicals*)
(* ::Text:: *)
(*integrateNestedRadicals is a Groebner basis-based method that can compute some otherwise crazily difficult integrals, for example:*)
(* ::Input:: *)
(*IntegrateAlgebraic[Sqrt[x^2+Sqrt[1+x^4]]/((-1+x^4)^2 Sqrt[1+x^4]),x]*)
(* ::Text:: *)
(*The answers to some of these nested radical integrals can be pretty wild. For example:*)
(* ::Input:: *)
(*IntegrateAlgebraic[(Sqrt[a^2 x^4+b] Sqrt[a x^2+Sqrt[a^2 x^4+b]])/(c x^2+d),x]*)
(* ::Subsubsection::Closed:: *)
(*integrateMultipleRadicals*)
(* ::Text:: *)
(*IntegrateAlgebraic can integrate both *)
(* ::Input:: *)
(*IntegrateAlgebraic[(Sqrt[x^4+1] Sqrt[x^2+Sqrt[x^4+1]])/(x^2+1),x]*)
(* ::Text:: *)
(*and *)
(* ::Input:: *)
(*IntegrateAlgebraic[(x^2+1)/((x^2-1) Sqrt[x^4+1]),x]*)
(* ::Text:: *)
(*however, we would also like it to integrate *)
(* ::Input:: *)
(*(x^2+1)/((x^2-1) Sqrt[x^4+1])+(Sqrt[x^4+1] Sqrt[x^2+Sqrt[x^4+1]])/(x^2+1)//Together*)
(* ::Text:: *)
(*integrateMultipleRadicals attempts to split the integrand into a sum of terms in a clever way. Note that it uses undocumented functionality of Apart. *)
(* ::Subsubsection::Closed:: *)
(*linearRationalIntegrate*)
(* ::Text:: *)
(*This routine tries a substitution of the form u == (x + a)/(x + b). For example, for the following integral*)
(* ::Input:: *)
(*IntegrateAlgebraic[(-1+x)/(x^3-x^2-x+1)^(1/3),x]*)
(* ::Text:: *)
(*IntegrateAlgebraic uses the substitution u == (x - 1)/(x + 1) to transform the integral to IntegrateAlgebraic[(2*u^(1/3))/(-1 + u)^2, u].*)
(* ::Subsubsection::Closed:: *)
(*integrateMultipleLinearRadical*)
(* ::Text:: *)
(*This method integrates any integrand in Q(x, (a x + b)^m1/2, (a x + b)^m2/2) using the substitution u == (Sqrt[a x + b] - Sqrt[a \alpha + b])/(Sqrt[c x + d] - Sqrt[c \alpha + d]). We go to some effort to pick a nice \alpha, but this could possibly be improved. *)
(* ::Subsubsection::Closed:: *)
(*integrateLinearRatioRadical*)
(* ::Text:: *)
(*This method integrates any integrand in Q(x, ((a x + b)/(c x + d))^(m1/n1), ((a x + b)/(c x + d))^(m2/n2), ...) with the substitution u^n == (a x + b)/(c x + d), where u = LCM[n1, n2, ...].*)
(* ::Subsubsection::Closed:: *)
(*integrateLinearRadical*)
(* ::Text:: *)
(*This method integrates any integrand in Q(x, (a x + b)^m1/n1, (a x + b)^m2/n2, ...) with the substitution u^n == (a x + b), where n = LCM[n1, n2, ...]. This method should work regardless of the size/complexity of the integrand (just like for rational function integration). For example *)
(* ::Input:: *)
(*IntegrateAlgebraic[(1-x^3 (4x+5)^(2/3)-x^5 (4x+5)^(1/5))/(1-x (4x+5)^(1/2)),x]*)
(* ::Subsubsection::Closed:: *)
(*integrateQuadraticRadical*)
(* ::Text:: *)
(*We can integrate all integrands in Q(x, (a x^2 + b x + c)^(m1/2), (a x^2 + b x + c)^(m2/2), ...) using Euler's substitution. Sometimes the Euler substitution method will produce integrals which are larger than necessary. Here's a nice example*)
(* ::Input:: *)
(*IntegrateAlgebraic[(1-Sqrt[1-x+x^2])/(x^4+x^2 Sqrt[1-x+x^2]-1),x]*)
(* ::Subsubsection::Closed:: *)
(*expandIntegrate*)
(* ::Text:: *)
(*After all the methods in IntegrateAlgebraic fail we try expanding the integrand and integrating term-by-term. This method is only used if "Expansion" -> True. The default is "Expansion" -> False, as this method can drastically increase the time it takes to compute an integral. *)
(* ::Subsubsection::Closed:: *)
(*apartIntegrate*)
(* ::Text:: *)
(*Like expandIntegrate, apartIntegrate is only used if all other methods in IntegrateAlgebraic have failed. This method can take even longer than expandIntegrate, however it means we can compute some really nice integrals. This method is only used if "Expansion" -> True.*)
(* ::Subsubsection::Closed:: *)
(*derivdivides*)
(* ::Text:: *)
(*The derivdivides method implemented the usual derivative divides heuristic and a Groebner basis-based method that seemingly outperforms CAS on many difficult integrals. For example*)
(* ::Input:: *)
(*int[(((4 x)/(-1+2 x^2)-(E^x-1/x)/(2 Sqrt[E^x-Log[x]])) Sqrt[Sqrt[-Sqrt[E^x-Log[x]]+Log[-1+2 x^2]]-Sqrt[1-Sqrt[E^x-Log[x]]+Log[-1+2 x^2]]])/(2 Sqrt[-Sqrt[E^x-Log[x]]+Log[-1+2 x^2]]),x]*)
(* ::Input:: *)
(*int[((E^x+ExpIntegralEi[x]) Sqrt[1+x ExpIntegralEi[x]-x^2 ExpIntegralEi[x]^2])/(x ExpIntegralEi[x]),x]*)
(* ::Subsubsection::Closed:: *)
(*Polynomial & rational functions*)
(* ::Text:: *)
(** We use Integrate for polynomial and rational functions (used for recursive calls in IntegrateAlgebraic). *)
(* ::Subsubsection::Closed:: *)
(*Methods we do not use*)
(* ::Text:: *)
(*Methods for algebraic functions that we do not implement include: *)
(**)
(** Davenport's extension to the Risch algorithm.*)
(** Trager's algorithm.*)
(** Bronstein's "lazy" Hermite reduction. *)
(** Kauers' method for computing the logarithmic part of the integral.*)
(** Miller's generalisation of Kauers' method.*)
(* ::Subsubsection::Closed:: *)
(*Some interesting examples*)
(* ::Text:: *)
(*Below are a handful of interesting examples:*)
(* ::Text:: *)
(*Examples from the paper (https://arxiv.org/abs/2004.04910): *)
(* ::Input:: *)
(*int[((-2+x^3) Sqrt[1-x^2+x^3])/(1+x^3)^2,x]*)
(*AlgebraicIntegrateHeuristic`Private`RationalSubstitution*)
(* ::Input:: *)
(*int[((x^4-1) Sqrt[x^4+1])/(x^8+1),x]*)
(* ::Text:: *)
(*My favourite examples thus far:*)
(* ::Input:: *)
(*int[((x^2-1) Sqrt[x^4+x^2+1])/((x^2+1) (x^4+x^3+x^2+x+1)),x]*)
(* ::Input:: *)
(*int[((x^4-1) Sqrt[1+x^4])/(1+3 x^2+x^4)^2,x]*)
(* ::Input:: *)
(*int[(-2+3 x^5)/((1+x^5) Sqrt[1+x^2+x^5]),x]*)
(* ::Input:: *)
(*int[(1+x^8)/((1-x^8) Sqrt[1-x^2+x^4]),x]*)
(* ::Input:: *)
(*int[(x^6-x^4)^(1/6),x]*)
(* ::Input:: *)
(*int[Sqrt[x^2+Sqrt[1+x^4]]/((1+x)^2 Sqrt[1+x^4]),x]*)
(* ::Input:: *)
(*int[(x-1)/((-3+x) (x^3-x^2-x+1)^(1/3)),x]*)
(* ::Text:: *)
(*We allow symbolic summation over the roots of a polynomial in the results.*)
(* ::Input:: *)
(*int[((x^8-1) (x^4-1)^(1/4))/(x^6 (x^8+1)),x]*)
(* ::Text:: *)
(*A difficult integral which was solved by Euler in 1777.*)
(* ::Input:: *)
(*int[(1-x^2)^2/((x^2+1) (x^4+6 x^2+1)^(3/4)),x]*)
(* ::Text:: *)
(*Some integrals with parameters which cause Risch-Trager-Bronstein to hang can be handled.*)
(* ::Input:: *)
(*int[(2 a^2 x^4-b^2)/((a^2 x^8-b^2) (a^2 x^4-b^2)^(1/4)),x]*)
(* ::Text:: *)
(*An example which AXIOM and Maple can compute, but FriCAS claims is not elementary.*)
(* ::Input:: *)
(*int[((-1+3 x^4) Sqrt[1+x+2 x^4+x^5+x^8])/(x^2 (4+x+4 x^4)),x]*)
(* ::Text:: *)
(*An example which Maple 2018 (with RootOf conversion) cannot compute as the radicand factors.*)
(* ::Input:: *)
(*int[((x^3+1) Sqrt[x^6-x^3-2])/(x^4 (x^6-2 x^3-1)),x]*)
(* ::Text:: *)
(*An example that AXIOM (August, 2014) claims is not elementary.*)
(* ::Input:: *)
(*int[(x^12-1)/((x^12+1) Sqrt[x^4+1]),x]*)
(* ::Text:: *)
(*We can now handle some integrals with rational radicands. The following example is computed with the generalised Gunther substitution method:*)
(* ::Input:: *)
(*int[(t^2+1)/((t^4-m t^2+1) Sqrt[(2 t^2-t-2)/(t^2+t-1)]),t]*)
(* ::Text:: *)
(*And this example is computed using the Laurent polynomial substitution code*)
(* ::Input:: *)
(*int[((1+3 x^4) (-a-b x+a x^4) ((-c-d x+c x^4)/(-e-f x+e x^4))^(1/3))/(x^2 (-a+b x+a x^4)),x]*)
(* ::Text:: *)
(*We can now handle some integrals with multiple distinct radicals (providing we can split them up and integrate term-by-term). For example*)
(* ::Input:: *)
(*int[((x^4+1) Sqrt[x^4-1]+(x^4-1) Sqrt[x^4+1])/(x^8+1),x]*)
(* ::Text:: *)
(*We now have a reasonable derivative-divides algorithm which can compute many otherwise difficult integrals. For example *)
(* ::Input:: *)
(*int[((-1+8 Sqrt[1-x] x^3+x^4) Sqrt[1-Sqrt[1-x]+Log[1-x^4]])/(2 Sqrt[1-x] (-1+x^4) Sqrt[1+Sqrt[1-x]-Log[1-x^4]]),x]*)
(* ::Text:: *)
(*We can now compute integrals which require factoring the radicand, integrating after introducing branch cuts, then correcting for these branch cuts without resorting to piecewise constants. For example*)
(* ::Input:: *)
(*int[Sqrt[-1-11 x-36 x^2-27 x^3+16 x^4+9 x^5+x^6],x]*)
(* ::Subsection::Closed:: *)
(*BeginPackage*)
BeginPackage["IntegrateAlgebraic`"];
IntegrateAlgebraic::usage = "IntegrateAlgebraic[f, x] is a heuristic for computing an elementary \
solution to a pseudo-elliptic integral.";
$verboseLevel::usage = "Controls how much information is shown when calling IntegrateAlgebraic. \
With $verboseLevel = 0; no information is shown, $verboseLevel = 1; only top level information is \
shown, $verboseLevel = 2; intermediate-level information is shown, and $verboseLevel = 3; shows all \
information.";
(*
solveAlgebraicIntegral::usage = "solveAlgebraicIntegral[f, x] is a heuristic for computing an \
elementary solution to a pseudo-elliptic integral. solveAlgebraicIntegral returns {rp, up, ip}, \
where rp is the (unintegrated) rational part, up is the unintegrated part, and ip is the \
integrated part.";
directRationalise::usage = "directRationalise[f, x] is an interface to the generalised \
Gunther code.";
derivdivides::usage = "derivative-divides heuristic.";
*)
Begin["`Private`"];
(* ::Subsection::Closed:: *)
(*IntegrateAlgebraic*)
ClearAll[IntegrateAlgebraic];
Options[IntegrateAlgebraic] = {
VerifySolutions -> True,
"MaxRationalDegree" -> 8,
"SubstitutionSize" -> "Small",
"DegreeBound" -> 8,
"LinearRational" -> True,
"Expansion" -> False,
"SingleStepTimeConstraint" -> 0.25,
"RationalUndeterminedOnly" -> False,
"FactorComplete" -> False,
"Radicals" -> False,
"DerivDivides" -> True
};
IntegrateAlgebraic[e_, x_, opts:OptionsPattern[]] /;
(algebraicQ[e, x] && ! PolynomialQ[e, x] && ! rationalQ[e, x] && Precision[e] === Infinity) := Module[
{integratedRationalPart, unintegratedPart, integratedPart, integral},
$recursionCounter = 0;
$timeConstraint = OptionValue["SingleStepTimeConstraint"];
If[$verboseLevel > 0,
$ProfileStartTime = AbsoluteTime[]];
{integratedRationalPart, unintegratedPart, integratedPart} = solveAlgebraicIntegral[e /. C -> internalC, x, opts];
If[unintegratedPart === 0,
integral = integratedPart + integratedRationalPart,
integral = integratedPart + integratedRationalPart + Defer[IntegrateAlgebraic][unintegratedPart, x]
];
integral /. internalC -> C
]
(* ::Subsection:: *)
(*solveAlgebraicIntegral*)
ClearAll[solveAlgebraicIntegral];
Options[solveAlgebraicIntegral] = Options[IntegrateAlgebraic];
solveAlgebraicIntegral[integrand_, x_, opts : OptionsPattern[]] :=
solveAlgebraicIntegral[integrand, x, opts] = Module[
{y, normalised, unintegratedRationalPart, start, u, dd, rationalPart, unintegratedPart, integratedPart,
rationalIntegrand, substitution, integral, linRat, result,
goursat, simplified, split, recuropts, integratedRationalPart},
If[++$recursionCounter > 32,
debugPrint1["Recursion limit for IntegrateAlgebraic exceeded! Giving up..."];
Return[ {0, integrand, 0} ]];
If[$verboseLevel > 0,
start = AbsoluteTime[]];
(* Rewrite the integrand in the form r(x)+(q[x]/h[x]) y^r, where
y \[Equal] p[x], r(x) is the non-algebraic (rational) part, and
q[x], h[x], p[x] are polynomials in x. *)
integratedPart = 0;
normalised = normalise[integrand, {x, y}];
{rationalPart, unintegratedPart} = {normalised[[5]], normalised[[1]]/normalised[[2]] /. normalised[[4]]};
If[rationalPart === 0,
unintegratedPart = integrand]; (* Fix/hack for IntegrateAlgebraic[1/((1 + x)*(x + x^3)^(1/4)), x]. SAMB 1123 *)
debugPrint2["normalised form of the integral is ", {rationalPart, unintegratedPart}];
(* Integrand is a rational function of x (needed for recursive integration). *)
If[unintegratedPart === 0 && rationalPart =!= 0,
debugPrint1["Integrand is in Q(x): ", rationalPart];
integral = integrate[rationalPart, x];
Return[ {0, 0, simplify[integral, x, "CancelRadicalDenominators" -> False, "Radicals" -> OptionValue["Radicals"]]}, Module ]
];
(* Chebychev integral of the form x^p (a x^r + b)^q is elementary iff
q, (p + 1)/r or q + (p + 1)/r is an integer. *)
If[chebychevIntegralQ[unintegratedPart, x],
debugPrint1["Trying chebyshevIntegrate..."];
integral = chebychevIntegrate[unintegratedPart, x, opts];
debugPrint1["chebyshevIntegrate returned ", integral];
If[integral =!= False && (TrueQ[! OptionValue[VerifySolutions]] || verifySolution[integral, unintegratedPart, x]),
Return[ {integrateRationalPart[rationalPart, x, opts], 0, integral}, Module ],
Return[ {rationalPart, unintegratedPart, integratedPart}, Module ](* Not integrable in terms of elementary functions. *)
]
];
(* Generalised Chebyshev integral (a x + b)^n (c x + d)^m, with IntegerQ[n + m] *)
If[MatchQ[unintegratedPart, (a_. x + b_)^n_Rational (c_. x + d_)^m_Rational /; FreeQ[{a, b, c, d}, x]],
debugPrint1["Trying generalisedChebychevIntegrate..."];
integral = generalisedChebychevIntegrate[unintegratedPart, x, opts];
debugPrint1["generalisedChebychevIntegrate returned ", integral];
If[integral =!= False && (TrueQ[! OptionValue[VerifySolutions]] || verifySolution[integral, unintegratedPart, x]),
Return[ {integrateRationalPart[rationalPart, x, opts], 0, integral}, Module ],
Return[ {rationalPart, unintegratedPart, integratedPart}, Module ](* Not integrable in terms of elementary functions. *)
]
];
(* Integrand is in Q(x, (a*x + b)^(1/2), (c*x + d)^(1/2)) *)
If[ListQ @ multipleLinearRadicalToRational[unintegratedPart, x, u],
debugPrint1["Integrand is in Q(x, (a*x + b)^(1/2), (c*x + d)^(1/2)): ", unintegratedPart];
integral = integrateMultipleLinearRadical[unintegratedPart, x, opts];
If[integral =!= False && TrueQ[! OptionValue[VerifySolutions]] || verifySolution[integral, unintegratedPart, x],
Return[ {integrateRationalPart[rationalPart, x, opts], 0, integral}, Module ]
]
];
(* Integrand is in Q(x, (a*x + b)^(m[1]/n[1]), (a*x + b)^(m[2]/n[2]), \[Ellipsis]) *)
If[ListQ @ linearRadicalToRational[unintegratedPart, x, u],
debugPrint1["Integrand is in Q(x, (a*x + b)^(m[1]/n[1]), (a*x + b)^(m[2]/n[2]), \[Ellipsis]): ", unintegratedPart];
integral = integrateLinearRadical[unintegratedPart, x, opts];
If[integral =!= False && (TrueQ[! OptionValue[VerifySolutions]] || verifySolution[integral, unintegratedPart, x]),
Return[ {integrateRationalPart[rationalPart, x, opts], 0, integral}, Module ],
Return[ {rationalPart, unintegratedPart, integratedPart}, Module ](* As this method should never fail. Review this decision. SAMB 0323 *)
]
];
(* Integrand is in Q(x,((a x + b)/(c x + d))^(m[1]/n[1]), ((a x + b)/(c x + d))^(m[2]/n[2]), \[Ellipsis]) *)
If[ListQ @ linearRatioRadicalToRational[unintegratedPart, x, u],
debugPrint1["Integrand is in Q(x,((a x + b)/(c x + d))^(m[1]/n[1]), ((a x + b)/(c x + d))^(m[2]/n[2]), \[Ellipsis]): ", unintegratedPart];
integral = integrateLinearRatioRadical[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[integral, unintegratedPart, x],
Return[ {integrateRationalPart[rationalPart, x, opts], 0, integral}, Module ],
Return[ {rationalPart, unintegratedPart, integratedPart}, Module ]
]
];
(* Quick integration heuristic for integrands with multiple radicals. *)
If[distinctRadicalCount[unintegratedPart, x] > 1,
debugPrint1["Integrand contains multiple distinct radicals."];
result = multipleRadicalQuickIntegrate[unintegratedPart, x, opts];
If[result =!= False && (TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x]),
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
]
];
(* Simple derivative divides. *)
If[OptionValue["DerivDivides"] && ! rootQ[unintegratedPart, x],
debugPrint1["Trying simple derivative-divides..."];
dd = derivdivides[unintegratedPart, x, u, "Fast" -> True];
If[ListQ[dd],
debugPrint1["Derivative-divides produced a simplification: ", dd];
simplified = dd[[1]];
substitution = dd[[2]];
recuropts = Append[DeleteCases[{opts}, HoldPattern["DerivDivides" -> _]], "DerivDivides" -> False];
result = solveAlgebraicIntegral[simplified, u, Sequence @@ recuropts];
(* TODO: what do we do if we couldn't integrate the simplified integrand? Do we
give up now, or try other methods on the original integrand? SAMB 0421 *)
(* result = simplify[result /. substitution, x, "Radicals" -> OptionValue["Radicals"]]; *)
result = result /. substitution;
debugPrint1["Substituting back for ", substitution, " gives ", result];
If[(TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x]),
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
]
]
];
If[! algebraicQ[unintegratedPart, x] && ! OptionValue["Expansion"],
Return[{integrateRationalPart[rationalPart, x, opts], unintegratedPart, integratedPart}, Module] (* As no further methods deal with non-algebraics. *)
];
(* Integrand is in Q(x, (a x^2 + b x + c)^(n[1]/2), (a x^2 + b x + c)^(n[2]/2), \[Ellipsis]) *)
If[ListQ @ quadraticRadicalToRational[unintegratedPart, x, u],
debugPrint1["Integrand is in Q(x, (a x^2 + b x + c)^(n[1]/2), (a x^2 + b x + c)^(n[2]/2), \[Ellipsis]): ", unintegratedPart];
integral = integrateQuadraticRadical[unintegratedPart, x, opts];
If[integral =!= False && (TrueQ[! OptionValue[VerifySolutions]] || verifySolution[integral, unintegratedPart, x]),
Return[ {integrateRationalPart[rationalPart, x, opts], 0, integral}, Module ],
Return[ {rationalPart, unintegratedPart, integratedPart}, Module ]
]
];
(* ... *)
(*
If[multipleRadicalsQ[unintegratedPart, x] && nestedCount[unintegratedPart, x] == 0,
Return[{Integrate[rationalPart, x], unintegratedPart, integratedPart}, Module] (* As no further methods deal with multiple radicals. *)
];
*)
(* Inverse function integration method. *)
If[ListQ @ inverseIntegrate[unintegratedPart, x, opts],
debugPrint1["Integrand is integrable using the inverse integration method."];
result = inverseIntegrate[unintegratedPart, x, opts];
If[result =!= False && TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
];
If[rootQ[unintegratedPart, x],
Return[{integrateRationalPart[rationalPart, x, opts], unintegratedPart, integratedPart}, Module] (* As no further methods deal with Root objects. *)
];
(* Nested radicals. *)
If[nestedCount[unintegratedPart, x] > 0,
debugPrint1["Integrand contains nested radicals: ", unintegratedPart];
(* Groebner basis-based direct rationalisation. *)
debugPrint1["Trying Groebner basis-based direct rationalisation on ", unintegratedPart];
If[ListQ @ decreaseNestedRadicals[unintegratedPart, x, u],
result = integrateNestedRadicals[unintegratedPart, x, u, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["integrateNestedRadicals returned : ", {rationalPart, unintegratedPart, integratedPart}]
];
(* Nested radical where the innermost radical is a quadratic. *)
debugPrint1["Trying nestedQuadraticRadicalIntegrate on ", unintegratedPart];
result = nestedQuadraticRadicalIntegrate[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["nestedQuadraticRadicalIntegrate returned : ", {rationalPart, unintegratedPart, integratedPart}]
];
(*
If[nestedCount[unintegratedPart, x] > 0,
Return[{Integrate[rationalPart, x], unintegratedPart, integratedPart}, Module](* As no further methods deal with nested radicals. *)
];
*)
(* Product rule integrate. *)
If[! OptionValue["RationalUndeterminedOnly"] && ! multipleRadicalsQ[unintegratedPart, x] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying productRuleIntegrate on ", unintegratedPart];
result = TimeConstrained[
productRuleIntegrate[unintegratedPart, x, opts],
10. OptionValue["SingleStepTimeConstraint"],
{0, unintegratedPart, 0}];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["productRuleIntegrate returned : ", {rationalPart, unintegratedPart, integratedPart}]
];
(* Decompose Integrate. *)
If[! OptionValue["RationalUndeterminedOnly"] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying polynomial decomposition of the radicand on ", unintegratedPart];
result = decomposeIntegrate[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["decomposeIntegrate returned : ", {rationalPart, unintegratedPart, integratedPart}]
];
(* Factoring the radicand(s) and taking branch cuts. *)
If[! OptionValue["RationalUndeterminedOnly"] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying factorisation of the radicand and taking branch cuts on ", unintegratedPart];
result = decreasePolynomialRadicandDegreeIntegrate[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["decreasePolynomialRadicandDegreeIntegrate returned : ", {rationalPart, unintegratedPart, integratedPart}]
];
If[! OptionValue["RationalUndeterminedOnly"] && nestedCount[unintegratedPart, x] == 0,
result = decreaseRationalRadicandDegreeIntegrate[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["decreaseRationalRadicandDegreeIntegrate returned : ", {rationalPart, unintegratedPart, integratedPart}]
];
(* Goursat pseudo-elliptic integral. *)
If[! OptionValue["RationalUndeterminedOnly"] && ! multipleRadicalsQ[unintegratedPart, x] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying Goursat method on ", unintegratedPart];
goursat = TimeConstrained[goursatIntegrate[unintegratedPart, x, u], $timeConstraint, False];
If[ListQ @ goursat,
integral = goursat // First;
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[integral, unintegratedPart, x],
unintegratedPart = 0;
integratedPart += integral
];
debugPrint1["Goursat returned : ", {rationalPart, unintegratedPart, integratedPart}];
]
];
(* Rational substitution with undetermined coefficients. *)
If[! multipleRadicalsQ[unintegratedPart, x] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying rational undetermined on ", unintegratedPart];
result = rationalUndeterminedIntegrate[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["Rational undetermined returned : ", {rationalPart, unintegratedPart, integratedPart}];
];
If[! OptionValue["RationalUndeterminedOnly"],
(* Direct rationalisation. *)
If[! multipleRadicalsQ[unintegratedPart, x] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying direct rationalisation on ", unintegratedPart];
result = directRationalise[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["direct rationalisation returned : ", {rationalPart, unintegratedPart, integratedPart}];
];
(* Linear rational substitution. *)
If[TrueQ[OptionValue["LinearRational"]] && ! multipleRadicalsQ[unintegratedPart, x] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying linear rational on ", unintegratedPart];
result = linearRationalIntegrate[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["LinearRational returned : ", {rationalPart, unintegratedPart, integratedPart}];
];
(* Factoring the radicand, partial power-expanding, then correcting for branch cuts. *)
If[! OptionValue["RationalUndeterminedOnly"] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying factorisation, partial power-expanding, then correcting for branch cuts on ", unintegratedPart];
result = radicandFactorIntegrate[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["radicandFactorIntegrate returned : ", {rationalPart, unintegratedPart, integratedPart}]
];
(* Solving for the logarithmic part with undetermined coefficients. *)
If[! multipleRadicalsQ[unintegratedPart, x] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying log part undetermined on ", unintegratedPart];
result = logPartIntegrate[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["logPart returned : ", {rationalPart, unintegratedPart, integratedPart}];
]
];
(* Last resort - factoring the radicand, power-expanding, then correcting for branch cuts. *)
If[! OptionValue["RationalUndeterminedOnly"] && nestedCount[unintegratedPart, x] == 0,
debugPrint1["Trying Factor, PowerExpand, integrating, then correcting for branch cuts on ", unintegratedPart];
result = powerExpandIntegrate[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["powerExpandIntegrate returned : ", {rationalPart, unintegratedPart, integratedPart}]
];
(* Partial fraction expansion and integrate term-by-term. *)
If[OptionValue["Expansion"] || reasonableExpansionQ[unintegratedPart, x],
(* Use partial fractions with a factorisation over Q. *)
debugPrint1["Trying partial fractions over Q on ", unintegratedPart];
result = apartIntegrate[unintegratedPart, x, opts, "FactorComplete" -> False];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["partialFractionIntegrate returned : ", {rationalPart, unintegratedPart, integratedPart}];
(* Use partial fractions with a factorisation over the splitting field of the integrand. *)
debugPrint1["Trying partial fractions over K on ", unintegratedPart];
result = apartIntegrate[unintegratedPart, x, opts, "FactorComplete" -> True];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["partialFractionIntegrate returned : ", {rationalPart, unintegratedPart, integratedPart}];
(* Expand and integrate term-by-term. *)
debugPrint1["Trying to integrate term-by-term on: ", unintegratedPart];
result = expandIntegrate0[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["expandIntegrate0 returned : ", {rationalPart, unintegratedPart, integratedPart}];
debugPrint1["Trying expansion into sum of terms with Expand on ", unintegratedPart];
result = expandIntegrate1[unintegratedPart, x, opts];
If[TrueQ[! OptionValue[VerifySolutions]] || verifySolution[result[[3]], unintegratedPart - result[[1]] - result[[2]], x],
rationalPart += result[[1]];
unintegratedPart = result[[2]];
integratedPart += result[[3]]
];
debugPrint1["expandIntegrate1 returned : ", {rationalPart, unintegratedPart, integratedPart}];
];
(* Try derivative-divides on the algebraic integral. *)
debugPrint1["Trying derivative-divides..."];