build.gradle

buildscript {
    repositories {
        mavenLocal()
        jcenter()
        mavenCentral()
    }
    dependencies {
        classpath 'org.jfrog.buildinfo:build-info-extractor-gradle:3.1.1'
        classpath 'com.github.jengelman.gradle.plugins:shadow:1.2.3'
    }
}

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'maven-publish'
apply plugin: 'com.jfrog.artifactory'
apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'checkstyle'
apply plugin: 'pmd'
apply plugin: 'jacoco'

apply from: "$rootDir/gradle/additional-artifacts.gradle"
apply from: "$rootDir/gradle/dependencies.gradle"
apply from: "$rootDir/gradle/documentation.gradle"
apply from: "$rootDir/gradle/publishing.gradle"
apply from: "$rootDir/gradle/release.gradle"

repositories {
    mavenLocal()
    jcenter()
    mavenCentral()
}

dependencies {
    compile group: "com.github.aap", name: "processor-tools", version: "0.0.5-SNAPSHOT", changing: true
    compile 'org.reactivestreams:reactive-streams:1.0.0'
    compile 'com.google.guava:guava:21.0'
    compile 'com.google.code.findbugs:jsr305:3.0.1'
    compile 'net.jodah:failsafe:1.0.3'
    compile 'org.slf4j:slf4j-api:1.7.21'
    compile 'javax.inject:javax.inject:1'
    testCompile ('org.testng:testng:6.8.21') 
    testCompile ('org.assertj:assertj-core:1.7.0') 
}

ext.compatibilityVersion = '1.8'
sourceCompatibility = compatibilityVersion
targetCompatibility = compatibilityVersion

jar {
    manifest {
        attributes 'Implementation-Title': "${project.name}",
                   'Implementation-Version': version,
                   'Built-By': System.getProperty('user.name'),
                   'Built-Date': new Date(),
                   'Built-JDK': System.getProperty('java.version'),
                   'Built-Gradle': gradle.gradleVersion
    }
}

checkstyle {
    toolVersion = "6.13"
}

pmd {
    ruleSetConfig = resources.text.fromFile(rootProject.file("config/pmd/pmd.xml"))
    consoleOutput = true
    ignoreFailures = false
    ruleSets = []
}

jacocoTestReport {
    reports {
        xml.enabled = true
        html.enabled = true
    }
}

tasks.withType(Pmd) {
    reports {
        xml.enabled = true
        html.enabled = true
    }
}

tasks.withType(JavaCompile) {
    options.compilerArgs += ["-Xlint:-options"]
}

tasks.withType(Test) {
    useTestNG()
    testLogging {
        showStandardStreams = true
        events 'started', 'passed', 'failed'
    }
}

check.dependsOn jacocoTestReport

task wrapper(type: Wrapper) {
    gradleVersion = '2.14.1'
    distributionUrl = "https://services.gradle.org/distributions/gradle-${gradleVersion}-all.zip"
}