Difference 2.3.5 vs. 2.3.6 using Epoch32Time()

[parallyze]

Hey Makuna,

sorry to bother you again. But this time it isn't about the timelib, so that's something else. ;)

As you've noticed I'm using your RTC library in my ClockSketch on Instructables. Yesterday somebody
asked me for help because he couldn't compile the sketch. While waiting for details I decided to test
a bit...

Tests done using Arduino IDE 1.8.13 and 1.8.18

This is DS3231_simple from your library @2.3.5:

// CONNECTIONS:
// DS3231 SDA --> SDA
// DS3231 SCL --> SCL
// DS3231 VCC --> 3.3v or 5v
// DS3231 GND --> GND

/* for software wire use below
#include <SoftwareWire.h>  // must be included here so that Arduino library object file references work
#include <RtcDS3231.h>

SoftwareWire myWire(SDA, SCL);
RtcDS3231<SoftwareWire> Rtc(myWire);
 for software wire use above */

/* for normal hardware wire use below */
#include <Wire.h> // must be included here so that Arduino library object file references work
#include <RtcDS3231.h>
RtcDS3231<TwoWire> Rtc(Wire);
/* for normal hardware wire use above */


void setup () 
{
    Serial.begin(57600);

    Serial.print("compiled: ");
    Serial.print(__DATE__);
    Serial.println(__TIME__);

    //--------RTC SETUP ------------
    // if you are using ESP-01 then uncomment the line below to reset the pins to
    // the available pins for SDA, SCL
    // Wire.begin(0, 2); // due to limited pins, use pin 0 and 2 for SDA, SCL
    
    Rtc.Begin();

    RtcDateTime compiled = RtcDateTime(__DATE__, __TIME__);
    printDateTime(compiled);
    Serial.println();

    if (!Rtc.IsDateTimeValid()) 
    {
        if (Rtc.LastError() != 0)
        {
            // we have a communications error
            // see https://www.arduino.cc/en/Reference/WireEndTransmission for 
            // what the number means
            Serial.print("RTC communications error = ");
            Serial.println(Rtc.LastError());
        }
        else
        {
            // Common Causes:
            //    1) first time you ran and the device wasn't running yet
            //    2) the battery on the device is low or even missing

            Serial.println("RTC lost confidence in the DateTime!");

            // following line sets the RTC to the date & time this sketch was compiled
            // it will also reset the valid flag internally unless the Rtc device is
            // having an issue

            Rtc.SetDateTime(compiled);
        }
    }

    if (!Rtc.GetIsRunning())
    {
        Serial.println("RTC was not actively running, starting now");
        Rtc.SetIsRunning(true);
    }

    RtcDateTime now = Rtc.GetDateTime();
    if (now < compiled) 
    {
        Serial.println("RTC is older than compile time!  (Updating DateTime)");
        Rtc.SetDateTime(compiled);
    }
    else if (now > compiled) 
    {
        Serial.println("RTC is newer than compile time. (this is expected)");
    }
    else if (now == compiled) 
    {
        Serial.println("RTC is the same as compile time! (not expected but all is fine)");
    }

    // never assume the Rtc was last configured by you, so
    // just clear them to your needed state
    Rtc.Enable32kHzPin(false);
    Rtc.SetSquareWavePin(DS3231SquareWavePin_ModeNone); 
}

void loop () 
{
    RtcDateTime tmp2 = Rtc.GetDateTime().Epoch32Time();
    
    if (!Rtc.IsDateTimeValid()) 
    {
        if (Rtc.LastError() != 0)
        {
            // we have a communications error
            // see https://www.arduino.cc/en/Reference/WireEndTransmission for 
            // what the number means
            Serial.print("RTC communications error = ");
            Serial.println(Rtc.LastError());
        }
        else
        {
            // Common Causes:
            //    1) the battery on the device is low or even missing and the power line was disconnected
            Serial.println("RTC lost confidence in the DateTime!");
        }
    }

    RtcDateTime now = Rtc.GetDateTime();
    printDateTime(now);
    Serial.println();

  RtcTemperature temp = Rtc.GetTemperature();
  temp.Print(Serial);
  // you may also get the temperature as a float and print it
    // Serial.print(temp.AsFloatDegC());
    Serial.println("C");

    delay(10000); // ten seconds
}

#define countof(a) (sizeof(a) / sizeof(a[0]))

void printDateTime(const RtcDateTime& dt)
{
    char datestring[20];

    snprintf_P(datestring, 
            countof(datestring),
            PSTR("%02u/%02u/%04u %02u:%02u:%02u"),
            dt.Month(),
            dt.Day(),
            dt.Year(),
            dt.Hour(),
            dt.Minute(),
            dt.Second() );
    Serial.print(datestring);
}

The only change I made is this line in loop():

RtcDateTime tmp2 = Rtc.GetDateTime().Epoch32Time();

Using 2.3.5 and compiling for nodeMCU or Arduino Nano does work as expected, IDE version does not matter.

Using 2.3.6 the added line throws an error in all combinations:

C:\Users\Daniel\Documents\Arduino\RTC_Makuna\RTC_Makuna.ino: In function 'void loop()':

RTC_Makuna:97:53: error: conversion from 'uint32_t {aka long unsigned int}' to non-scalar type 'RtcDateTime' requested
     RtcDateTime tmp2 = Rtc.GetDateTime().Epoch32Time();
             ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^~
Bibliothek Wire in Version 1.0 im Ordner: C:\Program Files (x86)\Arduino\hardware\arduino\avr\libraries\Wire  wird verwendet
Bibliothek Rtc_by_Makuna in Version 2.3.6 im Ordner: C:\Users\Daniel\Documents\Arduino\libraries\Rtc_by_Makuna  wird verwendet
exit status 1
conversion from 'uint32_t {aka long unsigned int}' to non-scalar type 'RtcDateTime' requested

Isn't getting Epoch32Time() supported in the way I'm using it?

Thanks,
Daniel

[Makuna]

time_t I believe is just a uint32_t; so anywhere below you could replace uint32_t with time_t and people were hitting it.

This line is incorrect

RtcDateTime tmp2 = Rtc.GetDateTime().Epoch32Time();

tmp2 was being constructed with the wrong time value, it takes a seconds from 2000/1/1. Epoch32Time is seconds since 1970/1/1.

Your assumption was a common issue that people were making.
Two issues were happening. Calling something like this...

uint32_t unixTime = Rtc.GetDateTime();

It doesn't return unix time so it was causing support issues and bugs in users code.
But, at the same time, they were also doing something like this which is what your statement really is doing...

RtcDateTime internet = unixTime;

Which is also wrong. The uint32_t constructor wasn't unix or epoch time; both of these worked in the Arduino time which was based on 2000/1/1.
To stop people from making these obvious assumptions, the constructor that took a uint32_t was made explicit, so no auto convert from uint32_t to RtcDateTime. AND the conversion constructor to uint32_t was removed completely.

[parallyze]

Thanks for the info. Because of some optional features inside the sketch I'm using different
time formats all the time, didn't have a single problem so far using it like mentioned. But I
changed this in all sketches, they compile fine now using 2.3.6 or older.

I was using tmp2 in that case in combination with second(); minute(); etc. from the time
library, other times I simply created RtcDateTime like this:
RtcDateTime(uint16_t year, uint8_t month, uint8_t dayOfMonth, uint8_t hour, uint8_t minute, uint8_t second)
Instead of RtcDateTime tmp2 = Rtc.GetDateTime().Epoch32Time(); and second(); minute(); etc I'm
now using RtcDateTime tmp2 = Rtc.GetDateTime() and its properties Second(); Minute(); etc, works
like a charm.

...and sometimes I'm using tm_elements. It's a bit messy, but seems to work in that scenario. ^^

Cheers,
Daniel