KeeYees Mini MP3 - another MP3-TF-16P

[softhack007]

Hi all,

I managed to get my "Mini MP3" up and running with your nice player library, however it needed some "special care" in the sketch void setup() function:

• wait until SD online
• send start command (0x0d) before first "play"
• polling the status with getStatus() to understand what's going on inside the chip.

I've also added a small function ask_status(), to parse the result of getStatus(), at least according to the datasheets I found.

Share and Enjoy :-)
Frank.

Hardware: "KeeYees Mini MP3 Player DFPlayer Module" (KYES65-KIT)

• price: around 8 Euro (as a "kit" with two small speakers)
  -Frontside is labelled "MP3-TF-16P"
  -Main chip on the backside is labelled "MH2024K-16SS" NO. 202103
  -pin layout is the same as original "DFPlayer Mini" module
  -it support the "Mp3ChipOriginal" command set, and requires packets with checksums

Below my sketch that works with my module.

// this example will play a track and then 
// every five seconds play the next track
//
// This version was adjusted to work smoothly with the "KeeYees Mini MP3 Player" module
// - some special care is needed during initalization (wait until online, and send start/stop before first "play" command)
// - don't use getTotalFolderCount(), because it will run into communication timeout (rx error 0x81)
// - added getStatus() calls, with evaluation of status code returned by the module
// Addtionally, I modified the example so that _all_ files are played (instead of just a few).
//
// Hardware:
// - product name is "KeeYees Mini MP3 Player DFPlayer Module" (KYES65-KIT)
// - price: around 8 Euro (as a "kit" with two small speakers)
// - Frontside is labeled "MP3-TF-16P"
// - Main chip on the backside is labeled "MH2024K-16SS" NO. 202103
// - pin layout is the same as original "DFPlayer Mini" module
// - it support the "Mp3ChipOriginal" command set, and requires packets with checksums
//
// This module can play MP3 and WAV format, however sometimes refuses to play some WAV files (unsupported sampling rates or codecs..). 
//  -> In this case, the "OnPlayFinished" notification does not come, and the module stays in mode "stopped playing".
// Converting the WAV file to MP3 format will usually solve the problem.
//
// This example expects the sd card to contain some mp3 or wav files
// but doesn't care whats in them
//
// sd:/0001.mp3
// sd:/0002.wav
// sd:/0003.mp3

#include <SoftwareSerial.h>
#include "DFMiniMp3.h"

// forward declare the notify class, just the name
//
class Mp3Notify; 

// define a handy type using serial and our notify class
//
//typedef DFMiniMp3<HardwareSerial, Mp3Notify> DfMp3; 

// instance a DfMp3 object, 
//
//DfMp3 dfmp3(Serial1);

// Some arduino boards only have one hardware serial port, so a software serial port is needed instead.
// comment out the above definitions and use these
SoftwareSerial secondarySerial(A2, A3); // RX, TX - can also be "analogue" ports
typedef DFMiniMp3<SoftwareSerial, Mp3Notify> DfMp3;
DfMp3 dfmp3(secondarySerial);

// implement a notification class,
// its member methods will get called 
//
class Mp3Notify
{
public:
  static void PrintlnSourceAction(DfMp3_PlaySources source, const char* action)
  {
    if (source & DfMp3_PlaySources_Sd) 
    {
        Serial.print("SD Card, ");
    }
    if (source & DfMp3_PlaySources_Usb) 
    {
        Serial.print("USB Disk, ");
    }
    if (source & DfMp3_PlaySources_Flash) 
    {
        Serial.print("Flash, ");
    }
    Serial.println(action);
  }
  static void OnError(DfMp3& mp3, uint16_t errorCode)
  {
    // see DfMp3_Error for code meaning
    Serial.println();
    Serial.print("Com Error 0x");
    Serial.println(errorCode, HEX);
  }
  static void OnPlayFinished(DfMp3& mp3, DfMp3_PlaySources source, uint16_t track)
  {
    Serial.print("Play finished for #");
    Serial.println(track);  
  }
  static void OnPlaySourceOnline(DfMp3& mp3, DfMp3_PlaySources source)
  {
    PrintlnSourceAction(source, "online");
  }
  static void OnPlaySourceInserted(DfMp3& mp3, DfMp3_PlaySources source)
  {
    PrintlnSourceAction(source, "inserted");
  }
  static void OnPlaySourceRemoved(DfMp3& mp3, DfMp3_PlaySources source)
  {
    PrintlnSourceAction(source, "removed");
  }
};


uint16_t numFiles = 0;
void setup() 
{
  int result;
  Serial.begin(115200);
  Serial.println("initializing...");
  
  dfmp3.begin();
  Serial.println("reset");
  dfmp3.reset();
  
  Serial.println("wait until SDCard is online");  
  do{
      result=dfmp3.isOnline();  // SD needs to be "online" before anyother command can be sent 
      waitMilliseconds(200);
  } while (result==false);
  
  Serial.print("volume ");
  dfmp3.setVolume(24);          // adjust volume (1..30)
  uint16_t volume = dfmp3.getVolume();
  Serial.println(volume);

  Serial.print("EQ ");           // module works more reliable if the EQ is set explicitly
  dfmp3.setEq(DfMp3_Eq_Normal);
  uint16_t eq = dfmp3.getEq();
  Serial.println(eq);
  
  Serial.print("files ");
  numFiles = dfmp3.getTotalTrackCount(DfMp3_PlaySource_Sd); // if you get an error here, re-format your SD card
  Serial.println(numFiles);

  ask_status();
  
  Serial.println("starting..."); 
  dfmp3.start();                  // module wants a "start" before the first "play"
  waitMilliseconds(100);
  dfmp3.stop();                  // we directly send "stop" to avoid random playback
  ask_status();

  if (numFiles < 1) numFiles=1; // .. just in case that getTotalTrackCount() returned an invalid value
}

void waitMilliseconds(uint16_t msWait)
{
  uint32_t start = millis();
  
  while ((millis() - start) < msWait)
  {
    // if you have loops with delays, its important to 
    // call dfmp3.loop() periodically so it allows for notifications 
    // to be handled without interrupts
    dfmp3.loop(); 
    delay(1);
  }
}

void ask_status()
{
  static uint16_t last_value = 0x8000;

  uint16_t value=dfmp3.getStatus();
  waitMilliseconds(20);

  if (value != last_value) // only print to serial monitor when status changes
  {
    Serial.print(F("status [0x")); Serial.print(value, HEX); Serial.print(F("] updated: "));
    // analyze MSB (most significant byte)
    if ((value & 0xF000) == 0x1000) Serial.print(F("Module SLEEP, "));
    if ((value & 0x0F00) == 0x0000) Serial.print(F("NO medium, "));
    if ((value & 0x0F00) == 0x0100) Serial.print(F("Flash drive, "));
    if ((value & 0x0F00) == 0x0200) Serial.print(F("SD card, "));
    // analyze LSB (least significant byte)
    if ((value & 0x00FF) == 0x00) Serial.print(F(" stopped playing"));
    if ((value & 0x00FF) == 0x01) Serial.print(F(" playing"));
    if ((value & 0x00FF) == 0x02) Serial.print(F(" paused playing"));
    Serial.println(F(""));
  }
  last_value = value;
}


void loop() 
{
  static int track=1;

  ask_status();
  Serial.print("play track #"); 
  Serial.println(track); 

  //dfmp3.playMp3FolderTrack(track); // sd:/mp3/0002.mp3
  dfmp3.playGlobalTrack(track);      // sd:/0001.mp3
  waitMilliseconds(100);
  ask_status();
  
  waitMilliseconds(5000);            // play current track for 5 seconds
  ask_status();
  
  track++;                           // advance track counter for next loop iteration
  if (track > numFiles) track = 1;
}

[seisfeld]

Did you try your Player with latest (not yet released) code?

#77

[softhack007]

yes, I tried it with the "master" branch.
Fun fact,: the chip is labelled MH2024K-16SS, but it only worked with the "normal" Mp3ChipOriginal driver class.

[seisfeld]

I also found that despite the same chip branding, the firmware might differ substantially...

[Makuna]

Oh wow, its even worse than I thought ;-)

[Makuna]

Yeah, all require that you wait until online. Some go online fast, some slower; I suspect this is due to the size and content amount on the flash card.

[softhack007]

probably true, as my SDcard is rather big (32GB SDHC).
It seems that my module needs ~700ms between "reset" and "online"

[softhack007]

Just out of curiosity, this is a serial monitor log from playing 3 short samples, where the second one is not a "supported format".

16:31:36.887 -> initializing...
16:31:36.887 -> reset
16:31:36.934 -> wait until SDCard is online

reset command took 47ms

16:31:37.637 -> SD Card, online (from OnPlaySourceOnline())
16:31:37.730 -> status [0x202] updated: SD card,  paused playing

700ms until card is "online" (32GB SDHC card)
Also note that initial state is "paused", not "stopped"

16:31:37.965 -> volume 24
16:31:38.059 -> EQ 0
16:31:38.199 -> files 3

counting files took 100ms

16:31:38.340 -> starting...
16:31:38.480 -> status [0x201] updated: SD card,  playing
16:31:38.762 -> status [0x200] updated: SD card,  stopped playing

This was my initial "start/stop" command sequence needed to get the module ready for playback.

16:31:38.902 -> play track #1
16:31:39.137 -> status [0x201] updated: SD card,  playing
16:31:42.277 -> OnPlayFinished(); Play finished for #1
16:31:42.324 -> status [0x200] updated: SD card,  stopped playing

Normal playback case. The track is ~3sec long, so the OnPlayFinished() message seems to come (correctly) after playback has completed.

16:31:44.386 -> play track #2

This is the "refused playback" case - module does not like the file format, does nothing and stays in mode "stopped"
Also note that there is no "notify" callback, also no error is reported.

16:31:49.917 -> play track #3
16:31:50.105 -> status [0x201] updated: SD card,  playing
16:31:53.104 -> OnPlayFinished(); Play finished for #3
16:31:53.151 -> status [0x200] updated: SD card,  stopped playing

Next file is playing, and OnPlayFinished() comes once after playback (~3 sec sample time)

[softhack007]

... and this is the log when i do not send the initial "start" command before the first playGlobalTrack().

It looks like the chip is resetting regularly (chip watchdog??)

17:42:51.276 -> play track #1
17:42:52.026 -> SD Card, online (from OnPlaySourceOnline())
17:43:02.010 -> 
17:43:02.010 -> OnError(): Com Error 0x81
17:43:02.104 -> status [0x0] updated: NO medium,  stopped playing
17:43:07.168 -> status [0x202] updated: SD card,  paused playing
17:43:07.262 -> play track #2
17:43:08.011 -> SD Card, online (from OnPlaySourceOnline())
17:43:17.995 -> 
17:43:17.995 -> OnError(): Com Error 0x81
17:43:18.089 -> status [0x0] updated: NO medium,  stopped playing
17:43:23.151 -> status [0x202] updated: SD card,  paused playing

[softhack007]

Log from successful "dfplayeranalyzer" run is here:
ghmartin77/DFPlayerAnalyzer#9

[Makuna]

This last week I updated the master branch with an initial set of changes to remove delays and respond to ACK/Error and retry commands. You will still need your "start" call I suspect; but I am interested if it solves other issues.

I also want to point you to DfMiniMp3Debug feature that will provide more details in the output.